Khi cần truyền nhiều dữ liệu nhanh – ghi thẻ nhớ, đọc bộ nhớ Flash, vẽ màn hình TFT – I²C trở nên chậm. SPI (Serial Peripheral Interface) chạy tới vài MHz trên Arduino Uno và truyền hai chiều cùng lúc. Bài này dùng SPI để ghi/đọc thẻ microSD – nền tảng cho dự án data logger ở bài #18.

1. Đấu nối module microSD

Hình 1. Đấu nối module microSD vào các chân SPI phần cứng của Uno.
Hình 1. Đấu nối module microSD vào các chân SPI phần cứng của Uno.
Tín hiệuChân UnoÝ nghĩa
SCKD13Xung nhịp do master (Arduino) tạo
MISOD12Master In – Slave Out: dữ liệu từ thẻ về Arduino
MOSID11Master Out – Slave In: dữ liệu từ Arduino tới thẻ
CS (SS)D10 (có thể đổi)Chọn thiết bị: LOW = đang nói chuyện với thẻ
Thẻ SD làm việc ở 3,3 V. Dùng module có sẵn ổn áp 3,3 V và IC chuyển mức (thường là 74LVC125). Các module "microSD adapter" chỉ có điện trở hoặc không có gì có thể làm hỏng thẻ khi dùng với Uno 5 V.

2. SPI truyền dữ liệu thế nào

Hình 2. SPI mode 0: master gửi 0xA5 và đồng thời nhận 0x3C trong 8 xung SCK.
Hình 2. SPI mode 0: master gửi 0xA5 và đồng thời nhận 0x3C trong 8 xung SCK.

Master kéo CS xuống để chọn thiết bị, rồi phát 8 xung SCK. Ở mỗi xung, một bit đi ra trên MOSI và đồng thời một bit đi vào trên MISO – SPI luôn là trao đổi: muốn đọc 1 byte, master phải gửi 1 byte (thường là 0xFF). Bốn "mode" SPI khác nhau ở cực tính xung nhịp và sườn lấy mẫu; thẻ SD dùng mode 0 và thư viện SD đã cấu hình sẵn.

3. Nhiều thiết bị trên cùng bus

Hình 3. Nhiều thiết bị SPI dùng chung 3 dây dữ liệu, mỗi thiết bị một chân CS riêng.
Hình 3. Nhiều thiết bị SPI dùng chung 3 dây dữ liệu, mỗi thiết bị một chân CS riêng.

SCK, MOSI, MISO dùng chung; mỗi thiết bị cần một chân CS riêng. Quy tắc quan trọng: tại mỗi thời điểm chỉ một CS ở mức LOW, và thiết bị không được chọn phải thả nổi MISO. Một số module rẻ không thả MISO đúng cách, làm hỏng giao tiếp của thiết bị khác – khi gặp lỗi khó hiểu, hãy thử từng module riêng.

Trên Uno, chân D10 phải để ở chế độ OUTPUT (thư viện SD tự làm) kể cả khi bạn dùng chân CS khác – nếu D10 là INPUT và bị kéo xuống, chip sẽ chuyển sang chế độ SPI slave và ngừng giao tiếp.

4. Ghi và đọc file trên thẻ

Định dạng thẻ FAT32 (thẻ ≤ 32 GB). Thư viện SD có sẵn trong Arduino IDE; tên file theo dạng 8.3 (tối đa 8 ký tự tên + 3 ký tự đuôi).

#include <SPI.h>
#include <SD.h>

const byte SD_CS = 10;

void setup() {
  Serial.begin(115200);
  if (!SD.begin(SD_CS)) {
    Serial.println(F("Khong khoi tao duoc the: kiem tra day, dinh dang FAT32"));
    while (true) {}                     // dừng tại đây
  }
  Serial.println(F("The SD san sang"));

  File f = SD.open("NHATKY.TXT", FILE_WRITE);   // FILE_WRITE = mở để ghi nối thêm
  if (f) {
    f.print(F("Khoi dong luc ms=")); f.println(millis());
    f.close();                          // close() mới thật sự ghi xuống thẻ
  } else {
    Serial.println(F("Loi mo file de ghi"));
  }

  f = SD.open("NHATKY.TXT");            // mở để đọc
  if (f) {
    while (f.available()) Serial.write(f.read());
    f.close();
  }
}

void loop() {}

5. Lỗi thường gặp

  • SD.begin() thất bại: thẻ exFAT/NTFS (thẻ 64 GB trở lên) – định dạng lại FAT32; dây SPI dài hoặc lỏng; nguồn 5 V yếu.
  • File rỗng sau khi rút nguồn: chưa gọi close() hoặc flush().
  • Hết RAM: thư viện SD dùng bộ đệm 512 byte – một phần tư RAM của Uno; tiết kiệm RAM ở phần còn lại của chương trình.

6. Bài tập

  1. Ghi giá trị A0 mỗi giây vào file CSV với dòng tiêu đề ms;a0, mở bằng Excel.
  2. Viết lệnh Serial READ để in toàn bộ file và CLEAR để xóa file (SD.remove()).
  3. Đo thời gian ghi 100 dòng với và không có close() sau mỗi dòng.

Bài tiếp theo: #9 – Ngắt ngoài và chống dội phím.

Tài liệu tham khảo