Đây là dự án tổng hợp của series: kết hợp I²C (bài #7), SPI và thẻ SD (bài #8), cảm biến DHT22 (bài #13), lập trình không chặn (bài #10). Kết quả là một bộ ghi dữ liệu chạy độc lập, có thể đặt trong kho, nhà kính, phòng máy và lấy dữ liệu bằng cách rút thẻ nhớ.
1. Kiến trúc và đấu nối

| Thiết bị | Chân thiết bị | Chân Uno |
|---|---|---|
| DS3231 | SDA / SCL / VCC / GND | A4 / A5 / 5V / GND |
| Module microSD | CS / MOSI / MISO / SCK | D10 / D11 / D12 / D13 |
| DHT22 | DATA (kéo lên 10 kΩ) | D2 |
| LED trạng thái | qua 220 Ω | D7 |
Vì sao cần DS3231 khi đã có millis()? millis() về 0 mỗi lần mất điện và sai lệch theo thạch anh của board. DS3231 có pin dự phòng, giữ giờ khi mất nguồn và sai số chỉ khoảng ±2 ppm (cỡ 1 phút/năm) ở nhiệt độ phòng.
2. Luồng chương trình

Mỗi ngày một file LOG_YYMMDD.CSV (tên 8.3 do thư viện SD giới hạn) giúp file không quá lớn và dễ tìm. File được mở, ghi một dòng rồi đóng ngay – nếu mất điện, tối đa chỉ mất dòng đang ghi.
3. Chương trình
Thư viện cần cài: RTClib (Adafruit), DHT sensor library (Adafruit); SD và Wire có sẵn.
#include <Wire.h>
#include <SPI.h>
#include <SD.h>
#include <RTClib.h>
#include <DHT.h>
RTC_DS3231 rtc;
DHT dht(2, DHT22);
const byte SD_CS = 10, LED = 7;
const unsigned long PERIOD = 60000UL; // ghi mỗi 60 s
unsigned long tLast = 0;
bool sdOk = false;
void blink(byte n, int ms) { for (byte i = 0; i < n; i++) { digitalWrite(LED, HIGH); delay(ms); digitalWrite(LED, LOW); delay(ms); } }
void setup() {
pinMode(LED, OUTPUT);
Serial.begin(115200);
dht.begin();
if (!rtc.begin()) { Serial.println(F("Khong thay DS3231")); while (true) blink(1, 100); }
if (rtc.lostPower()) rtc.adjust(DateTime(F(__DATE__), F(__TIME__))); // đặt giờ = lúc biên dịch
sdOk = SD.begin(SD_CS);
Serial.println(sdOk ? F("The SD san sang") : F("Loi the SD"));
tLast = millis() - PERIOD; // ghi ngay lần đầu
}
void loop() {
if (millis() - tLast < PERIOD) return;
tLast += PERIOD;
DateTime now = rtc.now();
float t = dht.readTemperature(), h = dht.readHumidity();
char name[13];
snprintf(name, sizeof name, "LOG_%02d%02d%02d.CSV", now.year() % 100, now.month(), now.day());
char line[48];
char ts[8], hs[8];
if (isnan(t)) strcpy(ts, "NaN"); else dtostrf(t, 4, 1, ts);
if (isnan(h)) strcpy(hs, "NaN"); else dtostrf(h, 4, 1, hs);
snprintf(line, sizeof line, "%04d-%02d-%02d %02d:%02d:%02d;%s;%s",
now.year(), now.month(), now.day(), now.hour(), now.minute(), now.second(), ts, hs);
Serial.println(line);
if (!sdOk) sdOk = SD.begin(SD_CS); // thử khởi tạo lại (thẻ vừa được cắm lại)
bool isNew = sdOk && !SD.exists(name);
File f = sdOk ? SD.open(name, FILE_WRITE) : File();
if (f) {
if (isNew) f.println(F("thoi_gian;nhiet_do_C;do_am_RH"));
f.println(line);
f.close();
blink(1, 40); // nháy ngắn = ghi thành công
} else {
sdOk = false;
blink(5, 60); // nháy nhanh = lỗi thẻ
}
}
dtostrf() được dùng vì snprintf trên AVR không hỗ trợ %f. Dùng dấu chấm phẩy làm phân cách để Excel tiếng Việt (dấu phẩy thập phân) mở đúng cột – nếu Excel của bạn dùng dấu chấm thập phân, đổi thành dấu phẩy.4. Phân tích dữ liệu

Mở file CSV bằng Excel (Data → From Text/CSV, chọn dấu phân cách Semicolon), chọn cột thời gian và hai cột số liệu để vẽ biểu đồ đường. Một ngày ghi mỗi phút tạo 1440 dòng, khoảng 50 KB – thẻ 8 GB đủ cho hàng trăm năm.
5. Hướng nâng cấp
- Tiết kiệm pin: dùng chân SQW của DS3231 làm báo thức đánh thức Arduino khỏi chế độ ngủ (thư viện LowPower).
- Màn hình LCD I²C hiển thị giá trị hiện tại và trạng thái thẻ (bài #7).
- Gửi dữ liệu lên mạng khi có Wi-Fi (bài #17), vẫn ghi thẻ làm bản dự phòng.
- Xem thêm dự án STM32 data logger dùng FatFs trên website để so sánh cách làm trên vi điều khiển 32 bit.
6. Bài tập
- Thêm nút nhấn "chuẩn bị rút thẻ": dừng ghi và bật LED xanh để báo an toàn.
- Cho phép đổi chu kỳ ghi qua Serial và lưu vào EEPROM (bài #15).
- Thêm cột điện áp pin (bài #5) và cảnh báo khi pin yếu.
Bài tiếp theo: #19 – Tối ưu và chống nhiễu.