DHT11 và DHT22 (AM2302) là cảm biến nhiệt độ – độ ẩm giá rẻ, chỉ cần một chân dữ liệu. Chúng rất phổ biến trong trạm thời tiết mini, nhà kính, tủ điện. Điều quan trọng là hiểu giới hạn của cảm biến và xử lý dữ liệu đúng cách để có số đo đáng tin.

1. Chọn DHT11 hay DHT22

DHT11DHT22 / AM2302
Dải nhiệt độ0–50 °C, ±2 °C−40–80 °C, ±0,5 °C
Dải độ ẩm20–80 % RH, ±5 %0–100 % RH, ±2–5 %
Độ phân giải1 °C, 1 %0,1 °C, 0,1 %
Tần suất đọc tối đa1 lần/giây1 lần/2 giây

Với ứng dụng cần độ chính xác cao hơn hoặc giao tiếp I²C, cân nhắc SHT31, BME280.

2. Đấu nối

Hình 1. Đấu nối DHT22: DATA vào D2 với điện trở kéo lên 10 kΩ.
Hình 1. Đấu nối DHT22: DATA vào D2 với điện trở kéo lên 10 kΩ.

Chân DATA cần điện trở kéo lên (4,7–10 kΩ) lên VCC. Module 3 chân bán sẵn thường đã có điện trở này; cảm biến rời 4 chân thì phải tự thêm. Với dây dài trên 5 m, dùng điện trở nhỏ hơn và nguồn 5 V.

3. Giao thức 1 dây

Hình 2. Giao thức 1 dây: độ dài mức HIGH phân biệt bit 0 và bit 1.
Hình 2. Giao thức 1 dây: độ dài mức HIGH phân biệt bit 0 và bit 1.

Arduino kéo đường DATA xuống thấp để "đánh thức" cảm biến, sau đó cảm biến trả lời và gửi 40 bit. Mỗi bit bắt đầu bằng 50 µs mức thấp; mức cao ngắn (~27 µs) là bit 0, mức cao dài (~70 µs) là bit 1. Byte cuối là checksum = tổng 4 byte trước (lấy 8 bit thấp). Thư viện tự đo thời gian và kiểm tra checksum – khi lỗi, nó trả về NaN.

Vì đo thời gian ở mức micro giây, việc đọc DHT bị ảnh hưởng nếu có ngắt chạy lâu (ví dụ thư viện LED NeoPixel, Servo nhiều kênh). Khi tỉ lệ lỗi cao, hãy đọc lại sau vài giây thay vì đọc liên tục.

4. Chương trình: đọc an toàn và lọc dữ liệu

Hình 3. Dữ liệu minh họa: lọc trung vị loại bỏ gai, EMA làm mượt.
Hình 3. Dữ liệu minh họa: lọc trung vị loại bỏ gai, EMA làm mượt.

Hai bước lọc bổ sung cho nhau: lọc trung vị 5 mẫu loại bỏ các giá trị bất thường đơn lẻ; EMA (trung bình trượt hàm mũ) làm mượt dao động nhỏ mà chỉ tốn một biến.

#include <DHT.h>                    // thư viện "DHT sensor library" (Adafruit)

DHT dht(2, DHT22);
float hist[5]; byte idx = 0, count = 0;
float rhFiltered = NAN;
unsigned long tRead = 0;
byte errors = 0;

float median5(float *a) {
  float b[5]; memcpy(b, a, sizeof b);
  for (byte i = 1; i < 5; i++)          // sắp xếp chèn
    for (byte j = i; j > 0 && b[j] < b[j - 1]; j--) { float t = b[j]; b[j] = b[j - 1]; b[j - 1] = t; }
  return b[2];
}

void setup() {
  Serial.begin(115200);
  dht.begin();
}

void loop() {
  if (millis() - tRead < 2000) return;   // DHT22: tối đa 1 lần / 2 s
  tRead = millis();

  float rh = dht.readHumidity();
  float t  = dht.readTemperature();
  if (isnan(rh) || isnan(t)) {           // lỗi checksum / mất kết nối
    if (++errors >= 5) Serial.println(F("CANH BAO: cam bien DHT khong phan hoi"));
    return;
  }
  errors = 0;

  hist[idx] = rh; idx = (idx + 1) % 5; if (count < 5) count++;
  float rhMed = (count == 5) ? median5(hist) : rh;
  rhFiltered = isnan(rhFiltered) ? rhMed : rhFiltered + 0.2 * (rhMed - rhFiltered);

  float heatIndex = dht.computeHeatIndex(t, rhFiltered, false);   // chỉ số cảm nhiệt (°C)
  Serial.print(F("T=")); Serial.print(t, 1);
  Serial.print(F(" C  RH=")); Serial.print(rhFiltered, 1);
  Serial.print(F(" %  CamNhiet=")); Serial.println(heatIndex, 1);
}

5. Lắp đặt để đo đúng

  • Đặt cảm biến tránh nắng trực tiếp, xa nguồn nhiệt (IC ổn áp, relay, LED công suất) – ngay cả nhiệt từ chính bo Arduino cũng làm sai vài độ.
  • Không để nước đọng trực tiếp lên cảm biến; ngoài trời dùng hộp chắn bức xạ (radiation shield) có lỗ thông gió.
  • Sau khi bị ẩm bão hòa lâu, cảm biến độ ẩm cần thời gian hồi phục.

6. Bài tập

  1. Hiển thị nhiệt độ, độ ẩm lên LCD I²C (bài #7).
  2. Bật quạt (qua MOSFET, bài #4) khi nhiệt độ > 32 °C, tắt khi < 30 °C.
  3. Tính điểm sương và cảnh báo nguy cơ đọng sương.

Bài tiếp theo: #14 – Đo khoảng cách với HC-SR04.

Tài liệu tham khảo