Thế giới thực là tín hiệu liên tục: vị trí núm vặn, điện áp pin, nhiệt độ, ánh sáng. Chân A0–A5 của Arduino được nối vào bộ chuyển đổi tương tự–số (ADC), biến điện áp 0–5 V thành con số để chương trình xử lý.

1. Đấu nối

Hình 1. Biến trở nối A0, module đo điện áp 0–25 V nối A1.
Hình 1. Biến trở nối A0, module đo điện áp 0–25 V nối A1.

Biến trở có 3 chân: hai chân ngoài nối 5V và GND, chân giữa (con chạy) nối A0. Xoay núm, điện áp ở chân giữa thay đổi từ 0 đến 5 V. Module cảm biến điện áp phổ biến thực chất chỉ là một mạch phân áp, ngõ ra S nối A1.

2. ADC 10 bit hoạt động thế nào

Hình 2. Đặc tuyến ADC 10 bit: 1024 mức, mỗi mức khoảng 4,88 mV.
Hình 2. Đặc tuyến ADC 10 bit: 1024 mức, mỗi mức khoảng 4,88 mV.

analogRead() trả về giá trị 0–1023 theo công thức giá_trị = Vin × 1024 / Vref. Với Vref = 5 V, mỗi bậc tương ứng 5 / 1024 ≈ 4,88 mV. Muốn đổi ngược ra điện áp:

V = analogRead(A0) × 5.0 / 1024.0

Mỗi lần đọc mất khoảng 100 µs, tức tối đa ~10 000 lần/giây – dư cho đa số cảm biến.

Vref không phải lúc nào cũng đúng 5 V. Khi cấp nguồn qua USB, điện áp 5V của board có thể chỉ 4,7–4,9 V, và toàn bộ phép đo lệch theo. Muốn đo chính xác: đo điện áp chân 5V bằng đồng hồ và dùng giá trị đó trong công thức, hoặc dùng tham chiếu nội 1,1 V (analogReference(INTERNAL)) cho tín hiệu nhỏ.

3. Đo điện áp lớn hơn 5 V

Hình 3. Mạch phân áp 30 kΩ / 7,5 kΩ chia điện áp vào cho 5.
Hình 3. Mạch phân áp 30 kΩ / 7,5 kΩ chia điện áp vào cho 5.

Không bao giờ đưa trực tiếp điện áp > 5 V vào chân analog. Mạch phân áp với R1 = 30 kΩ, R2 = 7,5 kΩ cho tỉ lệ 1/5: 25 V ở đầu vào chỉ còn 5 V ở chân A1. Đổi lại, độ phân giải giảm còn khoảng 24 mV mỗi bậc.

4. Chương trình: đọc, lọc trung bình và quy đổi

const float VREF = 5.00;          // thay bằng điện áp chân 5V đo thực tế
const float DIVIDER = 5.0;        // (30k + 7.5k) / 7.5k

int readAvg(uint8_t pin, uint8_t n = 16) {
  long sum = 0;
  for (uint8_t i = 0; i < n; i++) sum += analogRead(pin);
  return sum / n;                 // trung bình làm giảm nhiễu ngẫu nhiên
}

void setup() { Serial.begin(115200); }

void loop() {
  int pot = readAvg(A0);
  float vPot = pot * VREF / 1024.0;
  float vIn  = readAvg(A1) * VREF / 1024.0 * DIVIDER;
  int percent = map(pot, 0, 1023, 0, 100);

  Serial.print("Bien tro: "); Serial.print(percent); Serial.print(" % (");
  Serial.print(vPot, 2); Serial.print(" V)   Dien ap ngoai: ");
  Serial.print(vIn, 2); Serial.println(" V");
  delay(250);
}
map() chỉ làm việc với số nguyên. Khi cần kết quả lẻ (ví dụ 12,48 V), hãy tính bằng float như trên.

5. Các nguồn sai số và cách giảm

  • Nhiễu: lấy trung bình nhiều mẫu, thêm tụ 100 nF từ chân analog xuống GND, đi dây cảm biến ngắn.
  • Trở kháng nguồn tín hiệu cao: ADC hoạt động tốt nhất khi nguồn tín hiệu có trở kháng ≤ 10 kΩ. Khi đọc liên tiếp nhiều kênh có trở kháng cao, đọc bỏ lần đầu sau khi đổi kênh.
  • Sai số điện trở: điện trở 5 % làm hệ số phân áp lệch; hiệu chuẩn bằng cách đo một điện áp chuẩn và điều chỉnh hằng số DIVIDER.

6. Bài tập

  1. Hiển thị điện áp pin 9 V và cảnh báo khi dưới 7 V.
  2. Dùng biến trở điều khiển độ sáng LED (kết hợp bài #4).
  3. Đọc quang trở (LDR) qua phân áp 10 kΩ và vẽ ánh sáng trên Serial Plotter.

Bài tiếp theo: #6 – Serial UART cho debug và giao thức lệnh.

Tài liệu tham khảo