Arduino Uno không có kết nối mạng. Module ESP-01 chứa chip ESP8266 với firmware lệnh AT có sẵn biến thành "modem Wi-Fi": Arduino gửi lệnh dạng chữ qua UART, ESP8266 lo phần kết nối Wi-Fi và TCP/IP. Đây là cách kinh điển để đưa dữ liệu cảm biến lên Internet.

Lời khuyên trước khi bắt đầu: với dự án mới, lập trình trực tiếp ESP8266 (NodeMCU, Wemos D1) hoặc ESP32 bằng Arduino IDE thường đơn giản và ổn định hơn nhiều so với điều khiển bằng lệnh AT. Bài này vẫn hữu ích để hiểu giao tiếp module bằng lệnh AT – kỹ năng dùng lại cho module 4G, GPS, LoRa.

1. Đấu nối

Hình 1. ESP-01 cần nguồn 3,3 V riêng (≥ 500 mA) và phân áp trên chân RX.
Hình 1. ESP-01 cần nguồn 3,3 V riêng (≥ 500 mA) và phân áp trên chân RX.
  • Nguồn: ESP8266 kéo đỉnh khoảng 300 mA khi phát Wi-Fi. Chân 3.3V của Uno chỉ cấp được ~50 mA – không đủ. Dùng ổn áp AMS1117-3.3 lấy từ 5 V, thêm tụ 100 µF.
  • EN (CH_PD) nối 3,3 V để chip hoạt động.
  • RX của ESP chỉ chịu 3,3 V: phân áp 1 kΩ/2 kΩ từ chân TX mềm (D3) của Arduino.

2. Đổi baud về 9600

Firmware AT thường mặc định 115200 baud – quá nhanh với SoftwareSerial trên Uno. Lần đầu, kết nối ESP-01 qua USB–TTL 3,3 V (hoặc thử SoftwareSerial ở 115200 – có thể được vài lệnh) và gửi:

AT+UART_DEF=9600,8,1,0,0

Cấu hình này được lưu trong Flash của ESP8266. Từ đó Arduino giao tiếp ổn định ở 9600 baud.

3. Trình tự lệnh AT

Hình 2. Trình tự lệnh AT: chế độ Wi-Fi, kết nối, mở TCP, gửi HTTP, nhận phản hồi, đóng kết nối.
Hình 2. Trình tự lệnh AT: chế độ Wi-Fi, kết nối, mở TCP, gửi HTTP, nhận phản hồi, đóng kết nối.

Mỗi lệnh kết thúc bằng CR LF (\r\n); module trả về OK hoặc ERROR. Điểm mấu chốt khi lập trình là chờ đúng phản hồi với giới hạn thời gian, không dùng delay() cố định.

4. Chương trình gửi nhiệt độ lên ThingSpeak

#include <SoftwareSerial.h>
SoftwareSerial esp(2, 3);                       // RX, TX
const char *SSID = "TEN_WIFI", *PASS = "MAT_KHAU";
const char *KEY  = "WRITE_API_KEY";             // khóa ghi của kênh ThingSpeak

// gửi lệnh và chờ chuỗi mong đợi; trả về true nếu thấy trước khi hết giờ
bool at(const String &cmd, const char *expect, unsigned long timeout) {
  while (esp.available()) esp.read();           // xóa dữ liệu cũ
  esp.print(cmd); esp.print("\r\n");
  unsigned long t0 = millis();
  String resp;
  while (millis() - t0 < timeout) {
    while (esp.available()) {
      char c = esp.read();
      resp += c;
      if (resp.indexOf(expect) >= 0) return true;
      if (resp.length() > 200) resp.remove(0, 100);   // giữ bộ đệm nhỏ
    }
  }
  Serial.print(F("Loi/timeout: ")); Serial.println(cmd);
  return false;
}

bool sendValue(float value) {
  if (!at("AT+CIPSTART=\"TCP\",\"api.thingspeak.com\",80", "CONNECT", 8000)) return false;
  String req = String("GET /update?api_key=") + KEY + "&field1=" + String(value, 1) +
               " HTTP/1.1\r\nHost: api.thingspeak.com\r\nConnection: close\r\n\r\n";
  if (!at("AT+CIPSEND=" + String(req.length()), ">", 3000)) return false;
  bool ok = at(req, "SEND OK", 5000);
  at("AT+CIPCLOSE", "OK", 2000);
  return ok;
}

void setup() {
  Serial.begin(9600);
  esp.begin(9600);
  at("AT", "OK", 1000);
  at("AT+CWMODE=1", "OK", 1000);                // chế độ station
  at(String("AT+CWJAP=\"") + SSID + "\",\"" + PASS + "\"", "OK", 20000);
}

void loop() {
  float temp = analogRead(A0) * 500.0 / 1024;   // ví dụ LM35; thay bằng cảm biến của bạn
  Serial.println(sendValue(temp) ? F("Da gui") : F("Gui that bai"));
  delay(20000);                                 // ThingSpeak bản miễn phí: tối thiểu 15 s/lần
}
Ví dụ dùng String cho dễ đọc vì chỉ gửi mỗi 20 giây. Với chương trình chạy liên tục nhiều tháng, nên chuyển sang bộ đệm char cố định như bài #6 để tránh phân mảnh RAM. Không đưa mật khẩu Wi-Fi, khóa API lên kho mã công khai.

5. Lỗi thường gặp

Hiện tượngNguyên nhân
Ký tự rác, không thấy OKSai baud; SoftwareSerial ở 115200
Module reset, trả "ready" giữa chừngNguồn 3,3 V không đủ dòng – thêm ổn áp và tụ
FAIL khi CWJAPSai mật khẩu; mạng 5 GHz (ESP8266 chỉ hỗ trợ 2,4 GHz)
ERROR khi CIPSENDChưa mở được kết nối TCP, hoặc kết nối đã đóng

6. Bài tập

  1. Gửi thêm field2 = độ ẩm DHT22 (bài #13).
  2. Tự kết nối lại Wi-Fi khi gửi thất bại 3 lần liên tiếp.
  3. Viết lại toàn bộ chương trình trên ESP8266 NodeMCU (không cần Arduino Uno) và so sánh độ phức tạp.

Bài tiếp theo: #18 – Project data logger với SD và RTC.

Tài liệu tham khảo