Hai cảm biến gặp nhiều nhất trong dự án giám sát nhà xưởng, kho, tủ điện: BME280 đo môi trường không khí qua I2C, và DS18B20 – đầu dò nhiệt độ chống nước dùng giao tiếp 1-Wire, cắm vào bồn, ống, kho lạnh, nhiều đầu dò chung một dây.

Sau bài này bạn sẽ:
  • Đấu nối và đọc BME280, nhiều DS18B20.
  • Đọc không chặn, phát hiện cảm biến hỏng.
  • Lọc nhiễu, hiệu chuẩn, gửi JSON lên MQTT.

1. Đấu nối

Hình 1. Đấu nối BME280 qua I2C và DS18B20 qua 1-Wire có điện trở kéo lên 4,7 kΩ.
Hình 1. Đấu nối BME280 qua I2C và DS18B20 qua 1-Wire có điện trở kéo lên 4,7 kΩ.
BME280DS18B20
ĐoNhiệt độ ±1 °C, độ ẩm ±3 %RH, áp suất ±1 hPaNhiệt độ ±0,5 °C (−10 đến +85 °C)
Dải−40 đến +85 °C−55 đến +125 °C
Giao tiếpI2C (0x76 hoặc 0x77) hoặc SPI1-Wire, mã 64-bit riêng mỗi con
Thư việnAdafruit BME280OneWire + DallasTemperature
Module rẻ ghi "BME280" đôi khi là BMP280 (không đo độ ẩm). Kiểm tra mã chip: thư viện báo lỗi hoặc thanh ghi ID = 0x58 là BMP280, 0x60 là BME280.

2. Code đọc hai cảm biến

#include <Wire.h>
#include <Adafruit_BME280.h>
#include <OneWire.h>
#include <DallasTemperature.h>

Adafruit_BME280 bme;
OneWire oneWire(4);
DallasTemperature ds(&oneWire);
bool bmeOk = false;
uint32_t convStart = 0;
const uint32_t CONV_MS = 750;               // 12 bit

void setup() {
  Serial.begin(115200);
  Wire.begin(21, 22);
  bmeOk = bme.begin(0x76, &Wire);
  if (!bmeOk) Serial.println("Khong thay BME280 (thu 0x77?)");
  ds.begin();
  ds.setResolution(12);
  ds.setWaitForConversion(false);           // không chặn 750 ms
  Serial.printf("So dau do DS18B20: %d\n", ds.getDeviceCount());
  ds.requestTemperatures();
  convStart = millis();
}

void loop() {
  if (millis() - convStart >= CONV_MS) {    // đã đủ thời gian chuyển đổi
    int n = ds.getDeviceCount();
    for (int i = 0; i < n; i++) {
      float t = ds.getTempCByIndex(i);
      if (t == DEVICE_DISCONNECTED_C) {     // -127: đứt dây, lỏng tiếp xúc
        Serial.printf("DS%d: LOI\n", i);
      } else {
        Serial.printf("DS%d: %.2f C\n", i, t);
      }
    }
    if (bmeOk) {
      Serial.printf("BME: %.2f C, %.1f %%RH, %.1f hPa\n",
                    bme.readTemperature(), bme.readHumidity(), bme.readPressure() / 100.0f);
    }
    ds.requestTemperatures();               // bắt đầu chu kỳ đo tiếp
    convStart = millis();
  }
  // ... MQTT, web server chạy tự do trong lúc chờ
}
Hình 2. Thời gian chuyển đổi tối đa của DS18B20 theo độ phân giải.
Hình 2. Thời gian chuyển đổi tối đa của DS18B20 theo độ phân giải.

Không cần độ chính xác 0,0625 °C? Đặt 10 bit (0,25 °C, 187,5 ms) để đo nhanh hơn và tiết kiệm năng lượng.

3. Nhận diện từng đầu dò

getTempCByIndex(i) phụ thuộc thứ tự tìm thấy – thay một đầu dò là thứ tự có thể đổi. Hệ thống thật nên đọc địa chỉ 64-bit (ds.getAddress(addr, i)), ghi nhãn trên dây, lưu ánh xạ "địa chỉ → vị trí" vào NVS (bài #16) và đọc bằng ds.getTempC(addr).

4. Dữ liệu tin cậy

  • Lọc: trung bình trượt 5–10 mẫu hoặc trung vị 3 mẫu để loại gai nhiễu.
  • Kiểm tra hợp lý: loại giá trị ngoài dải vật lý (−127, 85,0 °C đúng lúc khởi động là giá trị mặc định của DS18B20 khi chưa đo xong), thay đổi bất thường quá nhanh.
  • Hiệu chuẩn: so với nhiệt kế chuẩn ở hai điểm (nước đá 0 °C, nhiệt độ phòng), lưu offset cho từng đầu dò vào NVS.
  • BME280 tự nóng: đặt xa ESP32 và LDO, đo ở chế độ forced (đo rồi ngủ) để giảm sai số nhiệt độ.
  • Dây dài: DS18B20 chạy tốt vài chục mét với cáp xoắn, giảm pull-up xuống 2,2 kΩ nếu dây dài; I2C không kéo dài quá 1 m.

5. Đóng gói và gửi

// Ví dụ payload gửi lên techvis/kho-a/may-01/telemetry (bài #9)
{"bme":{"t":28.41,"h":61.2,"p":1008.6},"ds":[{"id":"28FF6A1C0416","t":4.12},{"id":"28FF0B2D1117","t":-18.40}],"ok":true}

Tài liệu tham khảo